# Maintainer: David Runge <dvzrv@archlinux.org>

# WARNING: This upstream **does not** guarantee ABI stability. Expect soname changes in patch-level version bumps (https://github.com/wolfSSL/wolfssl/issues/6928)
pkgname=wolfssl
pkgver=5.8.2
pkgrel=1
pkgdesc="Lightweight, portable, C-language-based SSL/TLS library"
arch=(x86_64 aarch64)
url="https://www.wolfssl.com/"
license=(GPL-2.0-or-later)
depends=(glibc)
makedepends=(cmake)
provides=(libwolfssl.so)
# Workaround for some lto issues
options=(!lto)
source=(
  $pkgname-$pkgver-stable.tar.gz::https://github.com/$pkgname/$pkgname/archive/refs/tags/v$pkgver-stable.tar.gz
  https://github.com/$pkgname/$pkgname/releases/download/v$pkgver-stable/$pkgname-$pkgver-stable.tar.gz.asc
)
sha512sums=('29f52644966f21908e0d3f795c62b0f5af9cd2d766db20c6ed5c588611f19f048119827fe6e787ccc3ce676d8c97cf7ab409d996df0e3acb812d6cd01364de61'
            'SKIP')
b2sums=('58980c23998dcbb72dee433b76879e37c40b10e818d7a1004c885a10d476693ca846ddeccf03679c5afe9fbfb50c77d47b151cf4d0a23a508196ca864685e8a7'
        'SKIP')
validpgpkeys=(
  A2A48E7BCB96C5BECB987314EBC80E415CA29677  # wolfSSL <secure@wolfssl.com>
)

build() {
  local cmake_options=(
    -B build
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_INSTALL_PREFIX=/usr
    -D WOLFSSL_CURVE25519=ON
    -D WOLFSSL_CURVE448=ON
    -D WOLFSSL_ED25519=ON
    -D WOLFSSL_ED448=ON
    -D WOLFSSL_REPRODUCIBLE_BUILD=ON
    -D WOLFSSL_SNI=ON
    -D WARNING_C_FLAGS="$CFLAGS"
    -W no-dev
    -S $pkgname-$pkgver-stable
  )

  cmake "${cmake_options[@]}"
  cmake --build build --verbose
}

check() {
  cd build
  ./wolfcrypt/test/testwolfcrypt
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -vDm 644 $pkgname-$pkgver-stable/{README,ChangeLog}.md -t "$pkgdir/usr/share/doc/$pkgname/"
}
