# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Laurent Carlier <lordheavym@gmail.com>

pkgname=vulkan-tools
pkgver=1.4.328.0
pkgrel=1
pkgdesc="Vulkan tools and utilities"
url="https://www.vulkan.org/"
arch=(x86_64 aarch64)
license=(Apache-2.0)
depends=(
  gcc-libs
  glibc
  libx11
  libxcb
  vulkan-icd-loader
  wayland
)
makedepends=(
  cmake
  git
  glslang
  libxrandr
  ninja
  python
  spirv-tools
  volk
  vulkan-headers
  wayland-protocols
)
groups=(vulkan-devel)
source=("git+https://github.com/KhronosGroup/Vulkan-Tools#tag=vulkan-sdk-$pkgver")
b2sums=('68c7c2550e2cc4364fddef560732451631ae373ae415567faabb903481233544de96be2808de9851be1e9aa01411042f13a464adf557cd20c89acd4706c543fc')

build() {
  local cmake_options=(
    -D BUILD_ICD=OFF
    -D CMAKE_BUILD_TYPE=Release
    -D CMAKE_INSTALL_PREFIX=/usr
    -D CMAKE_INSTALL_SYSCONFDIR=/etc
    -D CMAKE_SKIP_INSTALL_RPATH=ON
  )

  cmake -S Vulkan-Tools -B build -G Ninja "${cmake_options[@]}"
  cmake --build build
}

check() {
  ctest --test-dir build --output-on-failure --stop-on-failure
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}

# vim:set sw=2 sts=-1 et:
