# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=uusi
pkgver=0.4.3.0
pkgrel=59
pkgdesc="Tweak .cabal files"
url="https://github.com/berberman/uusi"
license=("MIT")
arch=('x86_64' 'aarch64')
depends=('ghc-libs')
makedepends=('ghc')
checkdepends=('haskell-hunit')
source=("https://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz"
        "uusi-Cabal-3.6.patch")
sha512sums=('a7a7c7b352aba0edb33aa2c7663bfdc179ba5338281b72373670e57a1ed4c26ce1a6ae8c7f72e9841837bb43007b40715d70ee3408e4049fd47167b8151aeceb'
            '0ac55ca660f4b13790bd9b91e7f0501bc0c81b9a9a90e9c57edf013a287bcd6cbfdfd19375f51d41b85053d788f1c6d36f79d349c1b5865ac3fad44c916be045')

prepare() {
  cd $pkgname-$pkgver
  patch -p1 -i ../uusi-Cabal-3.6.patch
}

build() {
  cd $pkgname-$pkgver

  if (( CHECKFUNC )); then
    _opts=('--enable-tests')
  else
    _opts=('--disable-tests')
  fi

  runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname "${_opts[@]}" \
    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
    --ghc-option='-pie'

  runhaskell Setup build $MAKEFLAGS
}

check() {
  cd $pkgname-$pkgver
  runhaskell Setup test --show-details=direct
}

package() {
  cd $pkgname-$pkgver

  runhaskell Setup copy --destdir="$pkgdir"
  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
