# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: speps <speps at aur dot archlinux dot org>

pkgbase=sratom
pkgname=(sratom{,-docs})
pkgver=0.6.20
pkgrel=1
pkgdesc="An LV2 Atom RDF serialisation library"
arch=(x86_64 aarch64)
url="https://drobilla.net/software/sratom.html"
license=(ISC)
makedepends=(
  doxygen
  lv2
  meson
  python-sphinx
  python-sphinx-lv2-theme
  python-sphinxygen
  serd
  sord
)
source=(https://download.drobilla.net/$pkgname-$pkgver.tar.xz{,.sig})
sha512sums=('7a8a8c4997b683352ef64cbe1be7b3ada196640bc52be5e062a5d2dff42e8de7a06964c9368f7f04c3d089e09e18f775c644ab34615f99eb62bca3d4c5214bee'
            'SKIP')
b2sums=('1078b081cbfed7b922ebf7ae347d6e67f471e070b87cab09e08628433d87c35d78724824d37a270c113766588877f1c2b765f04d70442da0b4de780687a64135'
        'SKIP')
validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d@drobilla.net>

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

build() {
  arch-meson $pkgname-$pkgver build
  meson compile -C build
}

check() {
  meson test -C build
}

package_sratom() {
  depends=(
    glibc
    serd libserd-0.so
    sord libsord-0.so
    lv2
  )
  provides=(libsratom-0.so)
  optdepends=('sratom-docs: for developer documentation')

  meson install -C build --destdir "$pkgdir"
  (
    cd "$pkgdir"
    _pick $pkgname-docs usr/share/doc
  )
  install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname-$pkgver/{NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
}

package_sratom-docs() {
  pkgdesc+=" - documentation"

  mv -v $pkgname/* "$pkgdir"
  mv -v "$pkgdir/usr/share/doc/"sratom{-0,}
}
