# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>

_gemname='sqlite3'
pkgname="ruby-${_gemname}"
pkgver=2.8.0
pkgrel=1
pkgdesc='Ruby bindings for the SQLite3 embedded database'
url='https://github.com/luislavena/sqlite3-ruby'
arch=('x86_64' 'aarch64')
license=('BSD')
options=('!emptydirs')
depends=(
  ruby
  ruby-mini_portile2
  sqlcipher
  sqlite
)
makedepends=(
  ruby-bundler
  ruby-rake
  ruby-rake-compiler
  ruby-rake-compiler-dock
  ruby-rdoc
)
checkdepends=(
  ruby-minitest
)
source=("https://github.com/sparklemotion/sqlite3-ruby/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz")
sha512sums=('43493a5aef6c0514fa64286d35612dabca2d926abb84f6827638f3fcc81eeead1e611f5d615d3a3d30db25cb2d3267d539424a90e76e03117058e529e795ddf3')
b2sums=('6ff832dea938f3dd29a5cde3d2424202042bb993737f99a3056ea1e6707b757f404aa6b0aac87e3f46f82f6a37211319205ab024808665deda5f3a9d5aded887')

prepare() {
  cd "${_gemname}-ruby-${pkgver}"

  # update gemspec/Gemfile to allow newer version of the dependencies
  sed --in-place --regexp-extended \
    --expression 's|~>|>=|g' \
    "${_gemname}.gemspec"

  # remove rubocop
  rm --verbose rakelib/format.rake

  sed --in-place --regexp-extended \
    --expression 's|:rubocop, ||g' \
    Rakefile

  sed --in-place --regexp-extended \
    --expression '/rubocop/d' \
    Gemfile
}

build() {
  cd "${_gemname}-ruby-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  rake compile -- --enable-system-libraries --with-sqlcipher
  rake build

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "tmp_install${_gemdir}" \
    --bindir "tmp_install/usr/bin" \
    "pkg/${_gemname}-${pkgver}.gem"

  # remove unreproducible files
  rm --force --recursive --verbose \
    "tmp_install${_gemdir}/cache/" \
    "tmp_install${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
    "tmp_install${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"

  find "tmp_install${_gemdir}/gems/" \
    -type f \
    \( \
      -iname "*.o" -o \
      -iname "*.c" -o \
      -iname "*.so" -o \
      -iname "*.time" -o \
      -iname "gem.build_complete" -o \
      -iname "Makefile" \
    \) \
    -delete

  find "tmp_install${_gemdir}/extensions/" \
    -type f \
    \( \
      -iname "mkmf.log" -o \
      -iname "gem_make.out" \
    \) \
    -delete
}

check() {
  cd "${_gemname}-ruby-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install${_gemdir}" rake test
}

package() {
  cd "${_gemname}-ruby-${pkgver}"

  cp --archive --verbose tmp_install/* "${pkgdir}"

  install --verbose -D --mode=0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: ts=2 sw=2 et:
