# Maintainer: Collabora Ltd <ed.smith@collabora.com>

pkgname="repo-tool"
_srctag=mash-20250329.1
arch=("x86_64" "aarch64")
pkgver=${_srctag#mash-}
pkgrel=1
url="http://repo.steampowered.com"
license=("MIT" "Apache-2.0")
# We need rustup because the alpm libraries are bleeding edge
makedepends=(base-devel git rustup capnproto)
options=(!lto)
source=("git+https://gitlab.steamos.cloud/potato/mash/${pkgname}.git#tag=${_srctag}")
sha256sums=('SKIP')

prepare() {
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cd "${pkgbase}"
    cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cd "${pkgbase}"
    cargo build --release --frozen
}

check() {
    export RUSTUP_TOOLCHAIN=stable
    cd "${pkgbase}"
    cargo test --release --frozen
}

package() {
    pkgdesc="Faster replacement for repo-add"
    depends=(gcc-libs openssl glibc)
    export RUSTUP_TOOLCHAIN=stable

    cd "${pkgbase}"
    cargo install --no-track --frozen --offline --path repo-tool --root="$pkgdir/usr"
}
