# Maintainer: Collabora Ltd <ed.smith@collabora.com>

pkgbase="python-tools"
pkgname=(porttool mirrortool dockertool monorepotool imagetool python-tools-lib)
_srctag=mash-20250121.1
pkgver=${_srctag#mash-}
pkgrel=1
pkgdesc="Generate metadata for mash"
arch=("any")
url="http://repo.steampowered.com"
license=("MIT")
makedepends=(base-devel git python)
source=("${pkgbase}::git+https://gitlab.steamos.cloud/potato/mash/holo-ci-tools.git#tag=${_srctag}")
sha256sums=('SKIP')

build() {
    :
}

package_python-tools-lib() {
    cd "${pkgbase}"
    make install-lib DESTDIR="$pkgdir"
    install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}    

package_porttool() {
    depends=(
        python
        python-frozendict
        python-gitpython
        python-gpgme
        python-magic
        python-requests
        python-yaml
        python-zstandard
        python-tools-lib
    )
    cd "${pkgbase}"
    make install-porttool DESTDIR="$pkgdir"
    rm -rf "${pkgdir}/usr/lib"
    install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_mirrortool() {
   depends=(
        python
        python-frozendict
        python-gpgme
        python-magic
        python-requests
        python-yaml
        python-zstandard
        python-tools-lib
    )
    cd "${pkgbase}"
    make install-mirrortool DESTDIR="$pkgdir"
    rm -rf "${pkgdir}/usr/lib"
    install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_monorepotool() {
   depends=(
        python
        python-frozendict
        python-magic
        python-requests
        python-yaml
        python-zstandard
        python-tools-lib
    )
    cd "${pkgbase}"
    make install-monorepotool DESTDIR="$pkgdir"
    rm -rf "${pkgdir}/usr/lib"
    install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_imagetool() {
   depends=(
        python
        python-requests
        python-tools-lib
    )
    cd "${pkgbase}"
    make install-imagetool DESTDIR="$pkgdir"
    rm -rf "${pkgdir}/usr/lib"
    install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_dockertool() {
    depends=(
        python
        python-gpgme
        python-requests
        python-tools-lib
    )
    cd "${pkgbase}"
    make install-dockertool DESTDIR="$pkgdir"
    rm -rf "${pkgdir}/usr/lib"
    install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

