# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Blackleg <blacklg@openaliasbox.org>
# Contributor: Nidhogg
# Contributor: juantascon

pkgname=python-peewee
pkgver=3.18.3
pkgrel=1
pkgdesc="A small, expressive orm"
arch=('x86_64' 'aarch64')
url="https://github.com/coleifer/peewee"
license=('MIT')
depends=(
  'glibc'
  'python'
  'sqlite'
)
makedepends=(
  'cython'
  'python-build'
  'python-installer'
  'python-setuptools'
  'python-wheel'
)
checkdepends=(
  'python-apsw'
  'python-flask'
  'python-gevent'
  'python-psycopg2'
)
optdepends=(
  'python-psycopg2: for PostgreSQL database support'
  'python-pymysql: for MySQL database support'
)
source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('f3665284dc0da1a710f38561d337fbea3e85f6266515bf97be2ff218c0a7614aada9ae25ac9c4a971b72aff8be708647c2d5425635a20bf58b424d99877235fc')

prepare() {
  cd ${pkgname#python-}-$pkgver
  # Python 3.13 compatibility
  sed -i 's/isinstance(value, (int, long))/isinstance(value, int)/' \
    playhouse/_sqlite_ext.pyx
}

build() {
  cd ${pkgname#python-}-$pkgver
  python -m build --wheel --no-isolation
}

check() {
  cd ${pkgname#python-}-$pkgver
  python -m unittest discover -v
}

package() {
  cd ${pkgname#python-}-$pkgver
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
