# Maintainer: David Runge <dvzrv@archlinux.org>
# Maintainer: Christian Heusel <gromit@archlinux.org>

pkgname=python-cron-converter
pkgver=1.2.2
pkgrel=1.2
pkgdesc="Cron string converter for Python"
arch=(any)
url="https://github.com/Sonic0/cron-converter"
license=(MIT)
depends=(
  python
  python-dateutil
)
makedepends=(
  git
  python-build
  python-installer
  python-setuptools
  python-wheel
)
source=("$pkgname::git+$url.git#tag=v$pkgver")
sha512sums=('4c7619dcea434e50a84a3eb6a5a7ced7e3179d116604e093e21ae725087c38c1d729d3975c09051266110bd80b5c83b9412a156fc14543ed8a64dbb19e404780')
b2sums=('c67e886f665d490d1dd10598a222f0aa6dc3e9862a8dcc0a4446bf62b35d78e85d23a4c279a449ecdc41f27df25405d2112bb0efcfe09016c94ea75b2fa287b5')

prepare() {
  cd $pkgname
  # git cherry-pick -n 78a4113d6dd27e69dfe76fe9d2cd718a4c44ffd1
}

build() {
  cd $pkgname
  python -m build --wheel --no-isolation
}

check() {
  cd $pkgname
  python -m unittest discover -v tests/unit
  python -m unittest discover -v tests/integration
}

package() {
  cd $pkgname
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
