# Maintainer: Antonio Rojas <arojas@archlinux.org>

_pyname=contourpy
pkgname=python-$_pyname
pkgver=1.2.1
pkgrel=1.1
pkgdesc='Python library for calculating contours in 2D quadrilateral grids'
arch=(x86_64 aarch64)
url='https://github.com/contourpy/contourpy'
license=(BSD)
depends=(gcc-libs
         glibc
         python
         python-numpy)
makedepends=(meson-python
             pybind11
             python-build
             python-installer
             base-devel)
# checkdepends=(python-matplotlib
#               python-pytest
#               python-wurlitzer)
optdepends=('python-matplotlib: matplotlib renderer')
source=(https://pypi.python.org/packages/source/${_pyname:0:1}/$_pyname/$_pyname-$pkgver.tar.gz)
sha256sums=('4d8908b3bee1c889e547867ca4cdc54e5ab6be6d3e078556814a22457f49423c')

prepare() {
  sed -e '/ninja/d' -i $_pyname-$pkgver/pyproject.toml
}

build() {
  cd $_pyname-$pkgver
  python -m build --wheel --no-isolation
}

# check() {
#   cd $_pyname-$pkgver
#   python -m venv --system-site-packages test-env
#   test-env/bin/python -m installer dist/*.whl
#   test-env/bin/python -m pytest -v
# }

package() {
  cd $_pyname-$pkgver
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}
