# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

pkgbase=msgraph
pkgname=(
  msgraph
  msgraph-docs
)
pkgver=0.3.3
pkgrel=1
pkgdesc="A shared library for accessing MS Graph API"
url="https://gitlab.gnome.org/GNOME/msgraph"
arch=(x86_64 aarch64)
license=(LGPL-3.0-or-later)
depends=(
  gcc-libs
  glib2
  glibc
  json-glib
  libgoa
  libsoup3
)
makedepends=(
  gi-docgen
  git
  gobject-introspection
  meson
  uhttpmock
)
source=("git+https://gitlab.gnome.org/GNOME/msgraph.git#tag=$pkgver")
b2sums=('a800b4bdf8425aa8bfad65d217702ab6cf880a6a58b7ca632e9a6737f1e5bbeab45b14e1697f5cb727d8f9c5fb33fdbfa03188bc3ff736c08365b07f64efbabd')

prepare() {
  cd msgraph
}

build() {
  arch-meson msgraph build
  meson compile -C build
}

check() {
  meson test -vC build --print-errorlogs
}

package_msgraph() {
  meson install -C build --destdir "$pkgdir"
  provides=('libmsgraph-1.so')
  
  mkdir -p doc/usr/share
  mv {"$pkgdir",doc}/usr/share/doc
}

package_msgraph-docs() {
  pkgdesc+=" (documentation)"
  depends=()

  mv doc/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et:
