# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

pkgbase=malcontent
pkgname=(
  malcontent
  libmalcontent
)
pkgver=0.13.1
pkgrel=1
pkgdesc="Parental control support for applications"
url="https://gitlab.freedesktop.org/pwithnall/malcontent"
arch=(x86_64 aarch64)
license=(LGPL-2.1-or-later)
depends=(
  accountsservice
  appstream
  dbus
  flatpak
  gcc-libs
  glib2
  glibc
  gtk4
  hicolor-icon-theme
  libadwaita
  pam
  polkit
  python
  python-gobject
)
makedepends=(
  git
  glib2-devel
  gobject-introspection
  gtk-doc
  libglib-testing
  meson
  python-packaging
  yelp-tools
)
source=("git+https://gitlab.freedesktop.org/pwithnall/malcontent.git#tag=$pkgver")
b2sums=('25a9bfcfe4ea81260a73ba69640a0ae6ceb9645765d77ac5a6504173140ac9800dc0b7d493a6f59fa2ec8aa9bf4b34ccaff1554b5e585366302817bcca8f3d5b')
validpgpkeys=(
  923B7025EE03C1C59F42684CF0942E894B2EAFA0 # Philip Withnall <pwithnall@gnome.org>
)

prepare() {
  cd $pkgname
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

package_malcontent() {
  depends+=("libmalcontent=$pkgver-$pkgrel")
  provides=(libmalcontent-ui-1.so)
  groups=(gnome)

  meson install -C build --destdir "$pkgdir"

  cd "$pkgdir"

  _pick libs usr/include/malcontent-0
  _pick libs usr/lib/girepository-1.0/Malcontent-0.typelib
  _pick libs usr/lib/libmalcontent-0.so*
  _pick libs usr/lib/pkgconfig/malcontent-0.pc
  _pick libs usr/share/gir-1.0/Malcontent-0.gir
}

package_libmalcontent() {
  pkgdesc="Parental control library"
  depends=(
    gcc-libs
    glibc
    libg{lib,object,io}-2.0.so
  )
  provides=(libmalcontent-0.so)

  mv libs/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et:
