# Maintainer: Christian Hesse <mail@eworm.de>

pkgbase=libxcrypt
pkgname=(libxcrypt libxcrypt-compat)
pkgver=4.4.36
pkgrel=1.1
pkgdesc='Modern library for one-way hashing of passwords'
url='https://github.com/besser82/libxcrypt/'
license=('LGPL')
ncxfat_makedepends=('binutils' 'glibc' 'gcc')
ncxfab_makedepends=('base-devel' 'sh' 'make' 'coreutils')
options=(!lto)
install=libxcrypt.install
validpgpkeys=('678CE3FEE430311596DB8C16F52E98007594C21D') # Björn 'besser82' Esser
source=("${url}/releases/download/v${pkgver}/${pkgbase}-${pkgver}.tar.xz"{,.asc})
sha256sums=('e5e1f4caee0a01de2aee26e3138807d6d3ca2b8e67287966d1fefd65e1fd8943'
            'SKIP')

build() {
  mkdir build-libxcrypt build-libxcrypt-compat

  cd "${srcdir}/build-libxcrypt/"
  "${srcdir}/libxcrypt-${pkgver}"/configure \
    --prefix=$MPKG_USRPATH \
    --host=$MPKG_TARGETMACHINE \
    --disable-static \
    --enable-hashes=strong,glibc \
    --enable-obsolete-api=no \
    --disable-failure-tokens
  make
  
  cd "${srcdir}/build-libxcrypt-compat/"
  "${srcdir}/libxcrypt-${pkgver}"/configure \
    --prefix=$MPKG_USRPATH \
    --host=$MPKG_TARGETMACHINE \
    --disable-static \
    --enable-hashes=strong,glibc \
    --enable-obsolete-api=glibc \
    --disable-failure-tokens
  make
}

package_libxcrypt() {
  ncxfat_depends=('glibc')
  provides=('libcrypt.so')
  cd build-libxcrypt/

  make DESTDIR="${pkgdir}" install
}

package_libxcrypt-compat() {
  ncxfat_depends=('glibc' 'libxcrypt')
  provides=('libcrypt.so')
  pkgdesc='Modern library for one-way hashing of passwords - legacy API functions'
  
  cd build-libxcrypt-compat/

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"$MPKG_USRPATH/{include,lib/{lib*.so,pkgconfig},share}
}
