# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=libvpl
pkgver=2.15.0
pkgrel=1
pkgdesc='Intel Video Processing Library'
arch=('x86_64' 'aarch64')
url='https://intel.github.io/libvpl/'
license=('MIT')
depends=('gcc-libs' 'glibc')
optdepends=('vpl-gpu-rt: runtime implementation for Tiger Lake and newer GPUs')
optdepends_x86_64=('intel-media-sdk: runtime implementation for legacy Intel GPUs')
makedepends=('cmake')
provides=('onevpl' 'libvpl.so')
conflicts=('onevpl')
replaces=('onevpl')
options=('!emptydirs')
source=("https://github.com/intel/libvpl/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('7218c3b8206b123204c3827ce0cf7c008d5c693c1f58ab461958d05fe6f847b3')

build() {
    # fix warning: "_FORTIFY_SOURCE" redefined
    # note: upstream forces _FORTIFY_SOURCE=2
    export CFLAGS="${CFLAGS/-Wp,-D_FORTIFY_SOURCE=?/}"
    export CXXFLAGS="${CXXFLAGS/-Wp,-D_FORTIFY_SOURCE=?/}"
    
    export CFLAGS+=' -DNDEBUG'
    export CXXFLAGS+=' -DNDEBUG'
    cmake -B build -S "libvpl-${pkgver}" \
        -G 'Unix Makefiles' \
        -DCMAKE_BUILD_TYPE:STRING='None' \
        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
        -DCMAKE_INSTALL_SYSCONFDIR:PATH='/etc' \
        -DBUILD_EXAMPLES:BOOL='OFF' \
        -DBUILD_TESTS:BOOL='ON' \
        -DINSTALL_EXAMPLES:BOOL='OFF' \
        -DVPL_INSTALL_LICENSEDIR:PATH="share/licenses/${pkgname}" \
        -Wno-dev
    cmake --build build
}

check() {
    ctest --test-dir build --output-on-failure
}

package() {
    DESTDIR="$pkgdir" cmake --install build
    rm "${pkgdir}/"{etc/vpl/vars.sh,usr/include/vpl/preview/{,legacy/}README.txt}
}
