# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: ice-man <icemanf@gmail.com>

pkgname=libssh2
pkgver=1.11.0
pkgrel=1.1
pkgdesc="A library implementing the SSH2 protocol as defined by Internet Drafts"
url="https://www.libssh2.org/"
license=('BSD')
ncxfat_makedepends=(binutils openssl zlib gcc glibc)
ncxfab_makedepends=(base-devel sh make coreutils crosspacman)
validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2'   # Daniel Stenberg
              '914C533DF9B2ADA2204F586D78E11C6B279D5C91')  # Daniel Stenberg (old key)
source=("https://www.libssh2.org/download/libssh2-$pkgver.tar.gz"{,.asc})
sha256sums=('3736161e41e2693324deb38c26cfdc3efe6209d634ba4258db1cecff6a5ad461'
            'SKIP')

prepare() {
  cd "libssh2-$pkgver"

  autoreconf -fiv
}

build() {
  cd "libssh2-$pkgver"

  ./configure --prefix="$MPKG_USRPATH" --host="$MPKG_TARGETMACHINE" --disable-docker-tests --with-libssl-prefix="/usr/$MPKG_TARGETMACHINE"
  make
}

check() {
  make -C "libssh2-$pkgver" check
}

package() {
  ncxfat_depends=(openssl zlib)
  provides=('libssh2.so')

  cd "libssh2-$pkgver"

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
