# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
# Maintainer: Christian Hesse <eworm@archlinux.org>

pkgname='libnghttp3'
pkgver=1.2.0
pkgrel=1.1
pkgdesc="HTTP/3 library written in C"
url='https://github.com/ngtcp2/nghttp3'
license=('MIT')
ncxfab_makedepends=(base-devel sh coreutils crosspacman make autoconf)
ncxfat_makedepends=(binutils gcc glibc)
validpgpkeys=('F4F3B91474D1EB29889BD0EF7E8403D5D673C366') # Tatsuhiro Tsujikawa <tatsuhiro.t@gmail.com>
source=("https://github.com/ngtcp2/nghttp3/releases/download/v${pkgver}/nghttp3-${pkgver}.tar.xz"{,.asc})
sha256sums=('d2e216bae7bd7362f850922e4237a5caa204853b3594b22adccab4c1e1c1d1aa'
            'SKIP')

prepare() {
  cd nghttp3-${pkgver}
  autoreconf -i
}

build() {
  cd nghttp3-${pkgver}
  ./configure \
    --prefix=$MPKG_USRPATH \
    --host=$MPKG_TARGETMACHINE
  make
}

check() {
  cd nghttp3-${pkgver}
  make check
}

package() {
  provides=('libnghttp3.so')

  cd nghttp3-${pkgver}/lib
  make DESTDIR="${pkgdir}" install
  install -Dm644 ../COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et:
