# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: galiyosha@gmail.com
# Contributor: Jon Kristian Nilsen <jokr.nilsen@gmail.com>

pkgname=libffado
pkgver=2.4.8
pkgrel=1.1
pkgdesc="Driver for FireWire audio devices"
arch=(x86_64 aarch64)
url="http://www.ffado.org/"
license=('GPL-2.0-only or GPL-3.0-only')
depends=(
  gcc-libs
  glibc
  glibmm
  hicolor-icon-theme
  libiec61883
  libraw1394
  libxml++
  python-dbus
)
makedepends=(
  alsa-lib
  dbus-c++
  #jack
  libconfig
  #python-pyqt5
  scons
  base-devel
)
#optdepends=('python-pyqt5: ffado-mixer')
provides=(libffado.so)
source=(http://www.ffado.org/files/$pkgname-$pkgver.tgz)
sha512sums=('e891391ace53aa871d07ce244d38c5a3f1e622b6d289bb5ad5ed80255355cad14bc5dd36b6b54e9f3b2bd090b339c8688313204dbb8b391840941da0ef2abb94')
b2sums=('a64ba24510be21870a841ea37628d7012d64f318893a39c920d6b289cbaf6baa567f32501d5040c1a04a13169ba50e9f2773676887519c14b9ce3cbeff0a23ac')

prepare() {
  cd $pkgname-$pkgver
  # fix icon name, so it's coherent with XDG desktop file name
  sed -e 's/hi64-apps-ffado/ffado-mixer/g' -i support/xdg/ffado.org-ffadomixer.desktop
  # fix id, so it's coherent with XDG desktop file name
  sed -e 's/ffado.org-ffadomixer.desktop/ffado-mixer.desktop/g' -i support/xdg/ffado-mixer.appdata.xml
}

build() {
  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  local scons_options=(
    CUSTOM_ENV=True
    DEBUG=no
    MANDIR=/usr/share/man
    PREFIX=/usr
    PYPKGDIR=$site_packages
    PYTHON_INTERPRETER=/usr/bin/python
    UDEVDIR=/usr/lib/udev/rules.d
  )

  cd $pkgname-$pkgver
  scons "${scons_options[@]}"
}

package() {
  depends+=(
    alsa-lib libasound.so
    dbus-c++ libdbus-c++-1.so
    libconfig libconfig++.so
  )

  cd $pkgname-$pkgver
  scons DESTDIR="$pkgdir" WILL_DEAL_WITH_XDG_MYSELF=True install
  install -vDm 644 support/xdg/ffado.org-ffadomixer.desktop "$pkgdir/usr/share/applications/ffado-mixer.desktop"
  install -vDm 644 support/xdg/hi64-apps-ffado.png "$pkgdir/usr/share/icons/hicolor/64x64/apps/ffado-mixer.png"
  install -vDm 644 {AUTHORS,README} -t "$pkgdir/usr/share/doc/$pkgname/"
}

# vim:set ts=2 sw=2 et:
