# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

pkgname=libdex
pkgver=0.6.0
pkgrel=1.1
pkgdesc="A library supporting 'Deferred Execution'"
url="https://gitlab.gnome.org/GNOME/libdex"
arch=(x86_64 aarch64)
license=(LGPL-2.1-or-later)
depends=(
  glib2
  liburing
)
makedepends=(
  gi-docgen
  git
  gobject-introspection
  #libsoup3
  #libsysprof-capture
  meson
  vala
)
_commit=7a5757ea1b702e7fcf8312bcfe7a373ee89c787a  # tags/0.6.0^0
source=("git+$url.git#commit=$_commit")
b2sums=('12103636f413d169216532380cb693ccad8b317e90cebe5ebc83a46c299164acced58421a7365b4149cb19baae71db0ffaaea34fcb0cf40e9af1a4df87efcd99')

pkgver() {
  cd libdex
  git describe --tags | sed -r 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd libdex
}

build() {
  local meson_options=(
    -D docs=true
    #-D sysprof=true
  )

  arch-meson libdex build "${meson_options[@]}"
  meson compile -C build
}

check() (
  meson test -C build --print-errorlogs
)

package() {
  provides=(libdex-1.so)

  meson install -C build --destdir "$pkgdir"

  mkdir -p doc/usr/share
  mv {"$pkgdir",doc}/usr/share/doc
}

# package_libdex-docs() {
#   pkgdesc+=" (documentation)"
#   depends=()

#   mv doc/* "$pkgdir"
# }

# vim:set sw=2 sts=-1 et:
