# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=libatasmart
pkgver=0.19
pkgrel=7
pkgdesc='ATA S.M.A.R.T. reader and parser library'
arch=(x86_64 aarch64)
url='https://0pointer.de/blog/projects/being-smart.html'
license=(LGPL-2.1-or-later)
depends=(
  glibc
  systemd-libs
)
source=(
  "https://0pointer.de/public/$pkgname-$pkgver.tar.xz"
  0001-Dont-test-undefined-bits.patch
  0002-Drop-our-own-many-bad-sectors-heuristic.patch
)
b2sums=(
  7e2a9823c27eee5a41f93464b28236239891349639162c5fdc114c241a70fb39a3046c3de16ce402787cd86e13609fff0578bd26f7a2c994fefe3c9756d45968
  826c9ebce4aa299d57a9c3c410fa3fb0875f2eb92c9a4c5e27e384e78c316a86947dfbf5fa065b7cf9bc84a71948d8df47aa4a47129d4c316fa8f11815b8adcb
  6c96188d7cad73b8a7c6be8fa27ae297d6a6b32245bdde01050bbe5d1536b7e9618b7b2c5ffed41ca95d79b878dd84e2b9af7f1f2422e70fde54132646c93f8b
)

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 -i ../0001-Dont-test-undefined-bits.patch
  patch -Np1 -i ../0002-Drop-our-own-many-bad-sectors-heuristic.patch

  autoreconf -fi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --sbindir=/usr/bin
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}
