# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: Eric Belanger <belanger@astro.umontreal.ca>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=libasyncns
_version=0.8
pkgver=${_version}+r3+g68cd5af
pkgrel=3
epoch=1
pkgdesc="A C library for executing name service queries asynchronously"
url="https://0pointer.net/lennart/projects/libasyncns/"
arch=(x86_64 aarch64)
license=(LGPL)
depends=(glibc)
makedepends=(git lynx)
_commit=68cd5aff1467638c086f1bedcc750e34917168e4  # master
#source=("git+https://git.0pointer.net/clone/libasyncns.git#commit=$_commit")
source=(
  "http://0pointer.de/lennart/projects/libasyncns/libasyncns-0.8.tar.gz"
  "0001-minor-optimization.patch"
  "0002-add-link-to-bugzilla.patch"
  "0003-use-O_CLOEXEC-if-available.patch"
)

sha256sums=(
  '4f1a66e746cbe54ff3c2fbada5843df4fbbbe7481d80be003e8d11161935ab74'
  'SKIP'
  'SKIP'
  'SKIP')

prepare() {
  cd ${pkgname}-${_version}
  for src in "${source[@]}"; do
    [ -z "${src##*.patch}" ] || continue
    patch -p1 -i "${srcdir}/${src}"
  done
  NOCONFIGURE=1 ./bootstrap.sh
}

build() {
  cd ${pkgname}-${_version}
  ./configure --build=$CHOST --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --disable-static
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd ${pkgname}-${_version}
  make DESTDIR="$pkgdir" install
}

# vim:set sw=2 sts=-1 et:
