# Maintainer: Dave Reisner <dreisner@archlinux.org>

pkgname=kmod
pkgver=34.2
pkgrel=1
pkgdesc="Linux kernel module management tools and library"
arch=('x86_64' 'aarch64')
url='https://git.kernel.org/pub/scm/utils/kernel/kmod/kmod.git'
license=('LGPL-2.1-or-later' 'GPL-2.0-or-later')
depends=('glibc' 'zlib' 'openssl' 'xz' 'zstd')
makedepends=('git' 'meson' 'scdoc')
checkdepends=('linux-headers' 'libelf')
options=('strip')
provides=('libkmod.so')
validpgpkeys=('EAB33C9690013C733916AC839BA2A5A630CBEA53')  # Lucas DeMarchi
source=("git+https://git.kernel.org/pub/scm/utils/kernel/kmod/kmod.git#tag=v${pkgver}?signed"
        'depmod-search.conf'
        'depmod.hook'
        'depmod.script')
sha256sums=('7eef327c5cbe2a4649b2487b7a5bec6787cd26c9488bdbb2f35beb15305455b1'
            '1a92bfeae870f61ce814577e69d2a147a9c0caf6aed1131243e4179241fcc4a8'
            'c11c2a0f66ea405493e8617689ca10818dc81dd1dddc19bdb220c8b2917119c1'
            '18661aa40c25580f04d2ac3f32e54c2997c0994d1c829905537b413a9d291ac6')

build() {
  # Compute the kernel dir from the current (root)fs and don't use default
  # one as it's relying on ``uname -r`` which is broken in chroot/containers/...
  export KDIR=$(find /lib/modules/ -maxdepth 2 -mindepth 2 -type d -name build | sort | tail -1)

  arch-meson 'kmod' 'build' \
    -Dbuild-tests=true \
    -Dmanpages=true \
    -Dopenssl=enabled \
    -Dxz=enabled \
    -Dzlib=enabled \
    -Dzstd=enabled

  meson compile -C build
}

check() {
  # As of kmod v20, the test suite needs to build some kernel modules, and thus
  # needs headers available in order to run. We depend on linux-headers, but
  # this is really only to try and make sure that *some* useable tree of kernel
  # headers exist. The first useable tree we find is good enough, as these
  # modules will never be loaded by tests.

  meson test -C 'build'
}

package() {
  meson install -C 'build' --destdir "$pkgdir"

  # extra directories
  install -dm0755 "${pkgdir}"/{etc,usr/lib}/{depmod,modprobe}.d

  # install depmod.d file for search/ dir
  install -Dm0644 "${srcdir}/depmod-search.conf" "${pkgdir}/usr/lib/depmod.d/search.conf"

  # hook
  install -Dm0644 "${srcdir}/depmod.hook" "${pkgdir}/usr/share/libalpm/hooks/60-depmod.hook"
  install -Dm0755 "${srcdir}/depmod.script" "${pkgdir}/usr/share/libalpm/scripts/depmod"
}
