# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=tree-diff
pkgname=haskell-tree-diff
pkgver=0.3.0.1
pkgrel=219
pkgdesc="Diffing of (expression) trees"
url="https://github.com/phadej/tree-diff"
license=('BSD')
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-wl-pprint' 'haskell-ansi-terminal'
         'haskell-base-compat' 'haskell-hashable' 'haskell-parsers' 'haskell-primitive'
         'haskell-quickcheck' 'haskell-scientific' 'haskell-semialign' 'haskell-strict'
         'haskell-tagged' 'haskell-these' 'haskell-unordered-containers' 'haskell-uuid-types'
         'haskell-vector')
makedepends=('ghc' 'uusi' 'haskell-trifecta' 'haskell-tasty' 'haskell-tasty-golden'
             'haskell-tasty-quickcheck')
source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
sha512sums=('69244dcf5bca996e6c08500cf1841e68fda2a304fb811d788d2dd03e79076496bc12bfb1d3ac3f30c01929bbd617f009e2a78c1a7b23284cd41d1f78d8e6d20e')

prepare() {
    cd $_hkgname-$pkgver
    gen-setup
    uusi -d bytestring-builder -u QuickCheck -u ansi-terminal -u ansi-wl-pprint -u base-compat -u primitive -u tasty -u tasty-quickcheck
}

build() {
    cd $_hkgname-$pkgver

    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver

    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
