# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=tasty-inspection-testing
pkgname=haskell-tasty-inspection-testing
pkgver=0.2.1
pkgrel=308
pkgdesc="Inspection testing support for tasty"
url="https://github.com/Bodigrim/tasty-inspection-testing"
license=("MIT")
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-ghc' 'haskell-inspection-testing' 'haskell-tasty')
makedepends=('ghc' 'uusi')
source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
sha256sums=('5eb175659e7e5c0a4143b1453a067938b94e0926cab04822e4b3e1ba2ced8272')

prepare() {
  cd $_hkgname-$pkgver
  gen-setup
  uusi -u inspection-testing
}

build() {
  cd $_hkgname-$pkgver

  runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
    --ghc-option='-pie'

  runhaskell Setup build $MAKEFLAGS
  runhaskell Setup register --gen-script
  runhaskell Setup unregister --gen-script
  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
  cd $_hkgname-$pkgver

  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
  runhaskell Setup copy --destdir="$pkgdir"
  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
