# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=servant-server
pkgname=haskell-servant-server
pkgver=0.20.3.0
pkgrel=54
pkgdesc="A family of combinators for defining webservices APIs and serving them"
url="https://haskell-servant.readthedocs.org/"
license=('BSD-3-Clause')
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-base-compat' 'haskell-aeson' 'haskell-base64-bytestring'
         'haskell-constraints' 'haskell-http-api-data' 'haskell-http-media' 'haskell-http-types'
         'haskell-monad-control' 'haskell-network' 'haskell-servant' 'haskell-sop-core'
         'haskell-resourcet' 'haskell-tagged' 'haskell-transformers-base' 'haskell-wai'
         'haskell-wai-app-static' 'haskell-warp' 'haskell-word8')
makedepends=('ghc' 'haskell-hspec' 'haskell-hspec-wai' 'haskell-should-not-typecheck'
             'haskell-safe' 'haskell-wai-extra' 'haskell-temporary')
source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha512sums=('9fdbd1b8d161ede26a7f30e24adbcecb5f25321862dab84c9d94ddfd3cc20cf36848199dfd109f84a481c90a45801fefd5719a3c04f7bce698dbb3859fb49252')

build() {
    cd $_hkgname-$pkgver

    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver

    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
