# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=quickcheck-classes
pkgname=haskell-quickcheck-classes
pkgver=0.6.5.0
pkgrel=334
pkgdesc="QuickCheck common typeclasses"
url="https://github.com/andrewthad/quickcheck-classes#readme"
license=("BSD")
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-quickcheck' 'haskell-aeson' 'haskell-primitive'
         'haskell-primitive-addr' 'haskell-quickcheck-classes-base' 'haskell-semigroupoids'
         'haskell-semirings' 'haskell-vector')
makedepends=('ghc' 'uusi' 'haskell-base-orphans' 'haskell-tagged' 'haskell-tasty'
             'haskell-tasty-quickcheck')
source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
sha256sums=('62e32ad01c194798ebfb1a39ea9c06ccd54bd6d21cf726e9d0fc9db56b093ca6')

prepare() {
  cd $_hkgname-$pkgver
  gen-setup
  uusi -u primitive -u transformers
}

build() {
  cd $_hkgname-$pkgver

  runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
    --ghc-option='-pie'

  runhaskell Setup build $MAKEFLAGS
  runhaskell Setup register --gen-script
  runhaskell Setup unregister --gen-script
  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
  cd $_hkgname-$pkgver
  runhaskell Setup test --show-details=direct
}

package() {
  cd $_hkgname-$pkgver

  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
  runhaskell Setup copy --destdir="$pkgdir"
  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
