# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=indexed-traversable-instances
pkgname=haskell-indexed-traversable-instances
pkgver=0.1.2
pkgrel=123
pkgdesc="More instances of FunctorWithIndex, FoldableWithIndex, TraversableWithIndex"
url="https://github.com/haskellari/indexed-traversable"
license=("BSD")
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-indexed-traversable' 'haskell-onetuple' 'haskell-tagged'
         'haskell-unordered-containers' 'haskell-vector')
makedepends=('ghc' 'uusi' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-tasty'
             'haskell-tasty-quickcheck')
source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
sha256sums=('3c2bb62fba141d6696177070d63b88bc56b194bc60f6b73d2263b0244e2fc7c1')

prepare() {
  cd $_hkgname-$pkgver
  gen-setup
  uusi -u QuickCheck -u tasty-quickcheck
}

build() {
  cd $_hkgname-$pkgver

  runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
    --ghc-option='-pie'

  runhaskell Setup build $MAKEFLAGS
  runhaskell Setup register --gen-script
  runhaskell Setup unregister --gen-script
  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
  cd $_hkgname-$pkgver
  runhaskell Setup test --show-details=direct
}

package() {
  cd $_hkgname-$pkgver

  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
  runhaskell Setup copy --destdir="$pkgdir"
  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
