# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=hslua
pkgname=haskell-hslua
pkgver=2.3.0
pkgrel=192
pkgdesc="A Lua language interpreter embedding in Haskell"
url="https://hslua.org"
license=("MIT")
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-hslua-aeson' 'haskell-hslua-classes' 'haskell-hslua-core'
         'haskell-hslua-marshalling' 'haskell-hslua-objectorientation' 'haskell-hslua-packaging'
         'haskell-hslua-typing')
makedepends=('ghc' 'uusi' 'haskell-quickcheck' 'haskell-lua' 'haskell-lua-arbitrary'
             'haskell-quickcheck-instances' 'haskell-tasty' 'haskell-tasty-hslua'
             'haskell-tasty-hunit')
source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha512sums=('a3e4bd970d0a55465aafff91f6b03d29443599d819a48dc9f3296bcac5807c9cb2920cb5c6c5e3bda854403a5bea219b9a626305d932f8c452ff9cc09572d060')

prepare() {
    cd $_hkgname-$pkgver
    gen-setup
}

build() {
    cd $_hkgname-$pkgver

    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver

    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
