# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=hedgehog
pkgname=haskell-hedgehog
pkgver=1.2
pkgrel=19
pkgdesc="A modern property-based testing system"
url="https://hedgehog.qa"
license=("BSD")
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-async' 'haskell-barbies'
         'haskell-concurrent-output' 'haskell-erf' 'haskell-lifted-async' 'haskell-mmorph'
         'haskell-monad-control' 'haskell-pretty-show' 'haskell-primitive' 'haskell-random'
         'haskell-resourcet' 'haskell-transformers-base' 'haskell-wl-pprint-annotated')
makedepends=('ghc' 'uusi')
source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha512sums=('379ec7dd52b70bc8911d15a1f75317baaf3bf9d00f9d4a84490df8a83c885352600ff5f86499d2fac263fb3e01b3d0e1ffe34f9460934ed6f081ccfaa74d4429')

prepare() {
    cd $_hkgname-$pkgver
    gen-setup
} 

build() {
    cd $_hkgname-$pkgver

    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver

    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
