# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=free
pkgname=haskell-free
pkgver=5.2
pkgrel=117
pkgdesc="Monads for free"
url="https://github.com/ekmett/free/"
license=("BSD")
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-comonad' 'haskell-distributive' 'haskell-indexed-traversable'
         'haskell-profunctors' 'haskell-semigroupoids' 'haskell-th-abstraction'
         'haskell-transformers-base')
makedepends=('ghc' 'uusi')
source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha512sums=('f27a9cd9d2f29c442a8ae036be53cd22cd28279e15f394212713ad12be05e9a35dce72ae53647cad415833ff356228e5707b6ed85c1195f94cb57493f9341175')

prepare() {
    cd $_hkgname-$pkgver
    uusi -u semigroupoids
}

build() {
    cd $_hkgname-$pkgver
    
    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd $_hkgname-$pkgver
    
    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
