# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=cryptohash-sha256
pkgname=haskell-cryptohash-sha256
pkgver=0.11.102.1
pkgrel=189
pkgdesc="Fast, pure and practical SHA-256 implementation"
url="https://github.com/hvr/cryptohash-sha256"
license=("BSD")
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-base16-bytestring')
makedepends=('ghc' 'uusi' 'haskell-sha' 'haskell-tasty' 'haskell-tasty-hunit'
             'haskell-tasty-quickcheck')
source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha512sums=('fb4432050ab1236fc913ba50949ee52a117b0d74509b58868e8ade69bfc6e89e1379dfea48afc76d8527d4fdbaee9dd1d2dcea4530ba95a42441491df005e78c')

prepare() {
    cd $_hkgname-$pkgver
    uusi -u base -u tasty -u tasty-quickcheck
}

build() {
    cd $_hkgname-$pkgver

    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
            -fexe
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver

    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE

    mv "$pkgdir"/usr/bin/{,hs-}sha256sum
}
