# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=conduit-extra
pkgname=haskell-conduit-extra
pkgver=1.3.8
pkgrel=65
pkgdesc="Batteries included conduit: adapters for common libraries."
url="https://github.com/snoyberg/conduit"
license=("MIT")
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-conduit' 'haskell-network'
         'haskell-primitive' 'haskell-resourcet' 'haskell-streaming-commons' 'haskell-typed-process'
         'haskell-unliftio-core')
makedepends=('ghc' 'haskell-hspec' 'haskell-hspec-discover' 'haskell-quickcheck'
             'haskell-transformers-base')
source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha512sums=('b4011833f2c8ff30da82506cc703e67abbebc7faa12fe629098d97930572f428984b328e318adcd6bdc6ef3fd075df284eebe081855db4a8d12ba4df39279950')

build() {
    cd $_hkgname-$pkgver

    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver

    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
