# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=cassava
pkgname=haskell-cassava
pkgver=0.5.4.1
pkgrel=35
pkgdesc="A CSV parsing and encoding library"
url="https://github.com/haskell-hvr/cassava"
license=('BSD-3-Clause')
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-attoparsec' 'haskell-hashable' 'haskell-only' 'haskell-scientific'
         'haskell-text-short' 'haskell-unordered-containers' 'haskell-vector')
makedepends=('git' 'ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-quickcheck-instances'
             'haskell-test-framework' 'haskell-test-framework-hunit'
             'haskell-test-framework-quickcheck2')
source=("git+https://github.com/haskell-hvr/cassava.git#tag=v$pkgver")
sha512sums=('8a21b676c28a89b18dfc1d0bd6cd246d72c97f6eaeacd14067d737034064d2f4712ac21e9e36b26fe9f31e9784c7e6705b9cdf567d93b0a7361f4d7ca22b4f47')

build() {
    cd $_hkgname
    
    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname
    
    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
