# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=bsb-http-chunked
pkgname=haskell-bsb-http-chunked
pkgver=0.0.0.4
pkgrel=381.2
pkgdesc="Chunked HTTP transfer encoding for bytestring builders"
url="https://github.com/sjakobi/bsb-http-chunked"
license=('BSD')
arch=('aarch64')
depends=('ghc-libs')
makedepends=('ghc' 'uusi' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-hedgehog' 'haskell-tasty'
             'haskell-tasty-hedgehog' 'haskell-tasty-hunit' 'haskell-doctest')
source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz
        "fix-doctests.patch")
sha512sums=('74c04c2fd372067c42d3631cdfc2ad7093c0c3af1145833ab307c538dbb936d2042492d4e81c520c3adde8634df29ff8558822f06f226c52d16abb4a35ab1a13'
            'b89dd9fff663cde2cc95c8abb73290816815b2f5da7b4c1a7287792c8136cf8c5df9636f8e4a130b1fa37081e817fc859ee91dff3ebc52a787c60280fe46327f')

prepare() {
    cd $_hkgname-$pkgver
    uusi -u base -u bytestring
    patch -p1 -i ../fix-doctests.patch
}

build() {
    cd $_hkgname-$pkgver
    
    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver
    
    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
