# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=assoc
pkgname=haskell-assoc
pkgver=1.0.2
pkgrel=265
pkgdesc="swap and assoc: Symmetric and Semigroupy Bifunctors"
url="https://github.com/phadej/assoc"
license=('BSD')
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-bifunctors' 'haskell-tagged')
makedepends=('ghc' 'uusi')
source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
sha512sums=('20fd0056dcc2dff9504e090be5c2ef27692a795133620e60b9382cfdfbaf26d1019617acf48f0f762e22d699068bc4dbd35a714177ce3a36761c0065708b9168')

prepare() {
    cd $_hkgname-$pkgver
    gen-setup
    uusi -u base -u bifunctors $_hkgname.cabal
}

build() {
    cd $_hkgname-$pkgver    
    
    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver
    
    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
