# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

pkgname=gnome-session
pkgver=49.1
pkgrel=1
pkgdesc="The GNOME Session Handler"
url="https://gitlab.gnome.org/GNOME/gnome-session"
arch=(x86_64 aarch64)
license=(GPL-2.0-or-later)
depends=(
  dconf
  gcc-libs
  glib2
  glibc
  gnome-desktop-4
  gsettings-desktop-schemas
  gtk4
  json-glib
  systemd-libs
  xdg-desktop-portal-gnome
)
makedepends=(
  docbook-xsl
  git
  glib2-devel
  libxslt
  meson
  xmlto
)
conflicts=(gnome-mimeapps)
replaces=(gnome-mimeapps)
provides=(gnome-mimeapps)
groups=(gnome)
source=("git+https://gitlab.gnome.org/GNOME/gnome-session.git#tag=${pkgver/[a-z]/.&}")
b2sums=('d5c73719fe9dba6708a0431310b2b36461ffb16b0a3f94af96deaf11b70cbb811b73564a127bf657fe3e72c35b18aa08acceace1370e27ad213332ba0abf4ad8')

prepare() {
  cd $pkgname
}

build() {
  local meson_options=(
    -D docbook=true
    -D man=true
  )

  arch-meson $pkgname build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}

# vim:set sw=2 sts=-1 et:
