# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Maintainer: Andreas Radke <andyrtr@archlinux.org>

pkgname=ed
pkgver=1.20.1
pkgrel=1.1
pkgdesc="A POSIX-compliant line-oriented text editor"
license=('GPL')
url="https://www.gnu.org/software/ed/ed.html"
ncxfab_makedepends=('base-devel' 'sh' 'make' 'crosspacman' 'coreutils')
ncxfat_makedepends=('binutils' 'glibc' 'gcc')
options=('!emptydirs')
validpgpkeys=('1D41C14B272A2219A739FA4F8FE99503132D7742')  # Antonio Diaz Diaz
source=("https://ftp.gnu.org/gnu/ed/ed-$pkgver.tar.lz"{,.sig})
sha256sums=('b1a463b297a141f9876c4b1fcd01477f645cded92168090e9a35db2af4babbca'
            'SKIP')

build() {
  cd "ed-$pkgver"

  ./configure --prefix=$MPKG_ROOTPATH \
              --bindir=$MPKG_USRPATH/bin \
              --mandir=$MPKG_USRPATH/share/man \
              --infodir=$MPKG_USRPATH/share/info \
              CC="${MPKG_TOOLPREFIX}gcc" \
              "CPPFLAGS=$CPPFLAGS" \
              "CFLAGS=$CFLAGS" \
              "LDFLAGS=$LDFLAGS"

  make
}

check() {
  make -C "ed-$pkgver" check
}

package() {
  ncxfah_depends=('sh')
  ncxfat_depends=('glibc')
  make -C "ed-$pkgver" "DESTDIR=$pkgdir" install
}
