# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Johannes Löthberg <johannes@kyriasis.com>
# Contributor: Piotr Gorski <lucjan.lucjanov@gmail.com>
# Contributor: Lucy <lucy@luz.lu>
# Contributor: Bartlomiej Piotrowski <nospam@bpiotrowski.pl>

pkgname=pkgconf
pkgver=2.1.1
pkgrel=1.1
pkgdesc="Package compiler and linker metadata toolkit"
url="https://github.com/pkgconf/pkgconf"
license=(ISC)
ncxfat_makedepends=(
  binutils
  glibc
  gcc
)
ncxfab_makedepends=(
  base-devel
  sh
  git
  meson
)
provides=(
  libpkgconf.so
  pkg-config
  pkgconfig
)
conflicts=(pkg-config)
replaces=(pkg-config)
_commit=b6e04e2d47b4ca093632b9efde6303a137ea0634  # tags/pkgconf-2.1.1
source=(
  "git+$url#commit=$_commit"
  {x86_64-pc,i686-pc,aarch64}-linux-gnu.personality
  aarch64-cross-file.txt
)
b2sums=('SKIP'
        'c04583e19149c1035cb7777a59f0fbc4988b672d8e45105e33def3d0f9054464e33a400a3e7c7e8b99b334e4fe06aaa9d7e34662e806096d4374bd6b12d803db'
        '94c8fd12b5f33611fd6dbeae03b20e72bcf2937e764766e2633b2fd4c14925860d57eee234016c81b0563a47b112ac9ef4a8b3bb9fa3fc0dd266f355bc156c58'
        'afa98d03693dfda947902230b90513ecfc0facf5f0c6e985ee21d30a15a13dbc6fa253bcb1b7d072067f4646e2244b96389cd33f072f598c99e8567d486eb6e4'
        '637de9c28d7de609df6a7ae97c08f13ebb3ffe5abb91f6862f2dde7df2bf00edea63635f4b432d6d22342a4ccd0fd29af47641ad7fbc4195166f66aefcd06123')

pkgver() {
  cd pkgconf
  git describe --tags | sed 's/^pkgconf-//;s/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd pkgconf
}

build() {
  if (( MPKG_CROSSCOMPILED )); then
      CROSS_FILE="--cross-file ${MPKG_TARGETARCH}-cross-file.txt"
  fi
  
  local meson_options=(
      --prefix        $MPKG_USRPATH
      --libexecdir    lib
      --sbindir       bin
      --buildtype     plain
      --auto-features enabled
      --wrap-mode     nodownload
      -D              b_pie=true
      -D              python.bytecompile=1
      $CROSS_FILE        
      -D tests=disabled  # Tests need kyua
  )

  meson setup pkgconf build "${meson_options[@]}"

  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  ncxfah_depends=(sh)
  ncxfat_depends=(glibc)
  cah_depends=(pkgconf)

  # # FIXME: Disabled for multipkgbuild

  if (( MPKG_CROSSONLY )); then
      install -Dt "$pkgdir/usr/share/pkgconfig/personality.d" -m644 $MPKG_TARGETMACHINE.personality
      cat > "${MPKG_PKGPREFIX}pkgconf" <<EOF
#!/bin/sh
pkgconf --personality=$MPKG_TARGETMACHINE "\$@"
EOF
      install -Dt $pkgdir/usr/bin -m755 "${MPKG_PKGPREFIX}pkgconf"
      ln -s ${MPKG_PKGPREFIX}pkgconf "$pkgdir/usr/bin/${MPKG_PKGPREFIX}pkg-config"

  else
      meson install -C build --destdir "$pkgdir"

      ln -s pkgconf "$pkgdir$MPKG_USRPATH/bin/pkg-config"
      ln -s pkgconf.1 "$pkgdir$MPKG_USRPATH/share/man/man1/pkg-config.1"
  fi

  install -Dt "$pkgdir$MPKG_USRPATH/share/licenses/$pkgname" -m644 pkgconf/COPYING
}

# vim:set sw=2 sts=-1 et:
