# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>

pkgbase=libxslt
pkgname=(
  libxslt
  libxslt-docs
)
pkgver=1.1.39
pkgrel=1.1
pkgdesc="XML stylesheet transformation library"
url="https://gitlab.gnome.org/GNOME/libxslt/-/wikis/home"
license=(custom:MIT)
ncxfat_makedepends=(
  binutils
  gcc
  libgcrypt
  libxml2
  xz
)
ncxfab_makedepends=(
  base-devel
  crosspacman
  sh
  make
  sed
  coreutils
  git
  python
)
ncxfab_checkdepends=(
  docbook-xml
)
_commit=743ab691bed98ed11ac99bbd9d903d59fb814ab8  # tags/v1.1.39^0
source=(
  "git+https://gitlab.gnome.org/GNOME/libxslt.git#commit=$_commit"
  "0001-xsltproc-remove-maxparserdepth-option.patch"
)
b2sums=('SKIP'
        'def26d492d0a3097a26b4c11d77bf5f258cbb1b50951e51c3ad023f8951bf4c6eab18948b93a9f80e098dc0c34a303c1968057f7fb1ab7bd3548ecd34b6b3a3f')

pkgver() {
  cd libxslt
  git describe --tags | sed 's/-rc/rc/;s/^v//;s/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd libxslt
  patch -p1 < ../0001-xsltproc-remove-maxparserdepth-option.patch
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  local configure_options=(
    --prefix=$MPKG_USRPATH
    --build=$MPKG_BUILDMACHINE
    --host=$MPKG_TARGETMACHINE
    --sysconfdir=$MPKG_ETCPATH
    --localstatedir=/var
    --disable-static
    --with-python=/usr/bin/python
  )

  cd libxslt
  ./configure "${configure_options[@]}"
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd libxslt
  make check
}

package_libxslt() {
  ncxfat_depends=(
    libgcrypt
    libxml2
    xz
  )

  ncxfah_optdepends=('python: Python bindings')
  provides=(lib{,e}xslt.so)

  cd libxslt
  make DESTDIR="$pkgdir" install

  mkdir -p ../doc$MPKG_USRPATH/share
  mv "$pkgdir"$MPKG_USRPATH/share/{doc,gtk-doc} -t ../doc/$MPKG_USRPATH/share

  install -Dm644 Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_libxslt-docs() {
  pkgdesc+=" (documentation)"
  ncxfah_depends=()

  mv doc/* "$pkgdir"

  install -Dm644 libxslt/Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}

# vim:set sw=2 sts=-1 et:
