# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>

pkgname=expat
pkgver=2.6.2
pkgrel=1.1
pkgdesc="An XML parser library"
url="https://libexpat.github.io/"
license=(MIT)
ncxfab_makedepends=(base-devel cmake coreutils sh crosspacman)
ncxfat_makedepends=(binutils glibc gcc)
provides=(libexpat.so)
source=(https://github.com/libexpat/libexpat/releases/download/R_${pkgver//./_}/expat-$pkgver.tar.bz2{,.asc}
        aarch64.cmake
       )
sha512sums=('15811413e92a632272188781cc3f2a9e52ed62f6edfad9b2eeeca0946e53132b6c9ca6dc460eda766d6a4e68e5920128335d705f9556b5aa3f77593658780470'
            'SKIP'
            'SKIP')
b2sums=('9b518cf768e53b177fd933d37686a76c4a1bd1e2829cf414f8f9c054901f61d6445232eb4d4502e888507efa12a48d8ace206fbabac5d2ca5365f0437e971fd8'
        'SKIP'
        'SKIP')
validpgpkeys=(3176EF7DB2367F1FCA4F306B1F9B0E909AF37285) # Sebastian Pipping


build() {
  if (( MPKG_CROSSCOMPILED )); then
    local CROSS_OPT="-D CMAKE_TOOLCHAIN_FILE=$(realpath $srcdir/$MPKG_TARGETARCH.cmake)"
  fi
  
  local cmake_options=(
    -B build
    -D CMAKE_BUILD_TYPE=None
    $CROSS_OPT
    -D CMAKE_INSTALL_PREFIX=$MPKG_USRPATH
    -S expat-$pkgver
    -W no-dev
  )

    

  cmake "${cmake_options[@]}"
  cmake --build build --verbose
}

check() {
  ctest --test-dir build --output-on-failure
}

package() {
  ncxfat_depends=(glibc)
  DESTDIR="$pkgdir" cmake --install build
  install -vDm 644 expat-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 expat-$pkgver/{AUTHORS,Changes,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
}
