# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Anatol Pomozov <anatol.pomozov@gmail.com>

pkgname=cmocka
pkgver=1.1.7
pkgrel=1.1
pkgdesc='Elegant unit testing framework for C with support for mock objects'
url='https://cmocka.org/'
license=('Apache')
ncxfat_makedepends=('glibc' 'binutils' 'gcc')
ncxfab_makedepends=('cmake')
source=(https://cmocka.org/files/1.1/cmocka-${pkgver}.tar.xz{,.asc}
        aarch64.cmake)
sha512sums=('fe451893474dce1270e12af707a9a8fe1f0217e1782b4e1a67d25dadf56ff4a5e7dbc9ba4431f774aedffa46a40a28a6a0488df24feefb2f93e90fd2369c2c88'
            'SKIP'
            'SKIP')
validpgpkeys=('8DFF53E18F2ABC8D8F3C92237EE0FC4DCC014E3D') # Andreas Schneider <asn@cryptomilk.org>
options=('!lto')

prepare() {
  cd cmocka-${pkgver}
  mkdir -p build
}

build() {
  cd cmocka-${pkgver}/build

  if (( MPKG_CROSSCOMPILED )); then
    CROSSOPT="-DCMAKE_TOOLCHAIN_FILE=$(realpath ../../$MPKG_TARGETARCH.cmake)"
  fi

  cmake .. \
    $CROSSOPT \
    -DCMAKE_INSTALL_PREFIX=$MPKG_USRPATH \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=Release \
    -DUNIT_TESTING=ON
  make
}

check() {
  cd cmocka-${pkgver}/build
  make test
}

package() {
  ncxfat_depends=('glibc')
  cd cmocka-${pkgver}/build
  make install DESTDIR="${pkgdir}"
}

# vim: ts=2 sw=2 et:
