# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=alsa-lib
pkgver=1.2.11
pkgrel=1.1
cross=(nf)
pkgdesc="An alternative implementation of Linux sound support"
url="https://www.alsa-project.org"
license=(LGPL-2.1-or-later)
ncxfab_makedepends=(
  base-devel
  alsa-topology-conf
  alsa-ucm-conf
  glibc
)
provides=(
  libasound.so
  libatopology.so
)
install=alsa-lib.install
source=(
  $url/files/pub/lib/alsa-lib-$pkgver.tar.bz2{,.sig}
)
sha512sums=('7bf2c541dff5262c0302a1c716ca10cdb5105f4e0ad48f3341c3c7e975b0c3ea835a298a05974c3e216a85912c368d8025ba3cdda3ff04a7683133ce5b2a286d'
            'SKIP')
b2sums=('7fb245ffbfb841bdd5cb9da08fb2ec0a4ce8d340d4d1461999aca558c67c16e7c596cd0bffab761b7b4549025b0fb25462fb352e6d3900fb42f00b47de58d34c'
        'SKIP')
validpgpkeys=('F04DF50737AC1A884C4B3D718380596DA6E59C91') # ALSA Release Team (Package Signing Key v1) <release@alsa-project.org>

prepare() {
  cd alsa-lib-$pkgver
  autoreconf -fiv
}

build() {
  ncxfat_depends=(
    alsa-topology-conf
    alsa-ucm-conf
    glibc
  )
  # -flto=auto is not supported: https://github.com/alsa-project/alsa-lib/issues/110
  CFLAGS+=" -flto-partition=none"
  cd alsa-lib-$pkgver
  ./configure --prefix=$MPKG_USRPATH --without-debug
  # prevent excessive overlinking due to libtool
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  export LD_LIBRARY_PATH="alsa-lib-$pkgver/src/.libs/:$LD_LIBRARY_PATH"
  make -k check -C alsa-lib-$pkgver
}

package() {
  make DESTDIR="$pkgdir" install -C alsa-lib-$pkgver
  install -vDm 644 alsa-lib-$pkgver/{MEMORY-LEAK,TODO,NOTES,ChangeLog,doc/asoundrc.txt} -t "$pkgdir$MPKG_USRPATH/share/doc/$pkgname/"
}
