# Maintainer: Thomas Bächler <thomas@archlinux.org>

pkgname=acl
pkgver=2.3.2
pkgrel=1.1
pkgdesc='Access control list utilities, libraries and headers'
url='https://savannah.nongnu.org/projects/acl'
license=('LGPL')
ncxfab_makedepends=(base-devel sh make sed)
ncxfat_makedepends=(binutils attr glibc gcc libtool)
replaces=(xfsacl)
provides=(xfsacl 'libacl.so')
conflicts=(xfsacl)
validpgpkeys=('600CD204FBCEA418BD2CA74F154343260542DF34'  # Brandon Philips <brandon@ifup.co>
              'B902B5271325F892AC251AD441633B9FE837F581'  # Frysinger <vapier@gentoo.org>
              '259B3792B3D6D319212CC4DCD5BF9FEB0313653A') # Andreas Gruenbacher <andreas.gruenbacher@gmail.com>
source=("https://download.savannah.gnu.org/releases/acl/acl-${pkgver}.tar.gz"{,.sig})
sha256sums=('5f2bdbad629707aa7d85c623f994aa8a1d2dec55a73de5205bac0bf6058a2f7c'
            'SKIP')

build() {
  cd acl-$pkgver

  ./configure \
    --libdir="$MPKG_USRPATH/lib" \
    --libexecdir="$MPKG_USRPATH/lib" \
    --prefix="$MPKG_USRPATH" \
    --host="$MPKG_TARGETMACHINE"
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  ncxfat_depends=(glibc)
  cd acl-$pkgver

  make DESTDIR="${pkgdir}" install
}
