# Maintainer: Konstantin Gizdov <arch at kge dot pw>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Controbutor: Baptiste Jonglez <archlinux at bitsofnetworks.org>
# Contributor: nl6720 <nl6720@gmail.com>
# Contributor: Andreas B. Wagner <AndreasBWagner@pointfree.net>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Jeff Mickey <jeff@archlinux.org>

pkgname=yodl
pkgver=4.05.01
pkgrel=1
pkgdesc='Implements a pre-document language and tools to process it.'
arch=(x86_64 aarch64)
url='https://fbb-git.gitlab.io/yodl/'
license=(AGPL-3.0-or-later)
depends=(bash)
makedepends=(icmake)
_archive="$pkgname-$pkgver"
source=("https://gitlab.com/fbb-git/$pkgname/-/archive/$pkgver/$_archive.tar.gz")
sha512sums=('92f9eff80996d81dbc52f4dfe75e4f485d3e23e25f5d1fb64444ca706abe8d34fed480533b2c7bb0a91898e86636dde099a86447630b9d77e2d56965a17ab39a')

build() {
	cd "$_archive/$pkgname"
        CXXFLAGS+=' --std=c++20'
        export CXXFLAGS
	./build programs
	./build macros
	./build man
	./build html
}
package() {
	cd "$_archive/$pkgname"
	./build install programs "$pkgdir"
	./build install macros "$pkgdir"
	./build install man "$pkgdir"
	./build install manual "$pkgdir"
}
