# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=towncrier
pkgver=25.8.0
pkgrel=1
pkgdesc="Utility to produce useful, summarised news files for your project"
arch=('any')
url="https://github.com/twisted/towncrier"
license=('MIT')
depends=(
  'python'
  'python-click'
  'python-jinja'
)
makedepends=(
  'git'
  'python-build'
  'python-installer'
  'python-hatchling'
)
checkdepends=(
  'python-twisted'
  'mercurial'
)
source=("git+https://github.com/twisted/towncrier.git#tag=$pkgver")
sha512sums=('2d06a4253ab2ad12a944f221ff340bc28c2daff04e9f9b740ad2447cdcae063522083160ebf5c9e0da4675d4545f124511741ef60b2a020a0aefc9788f1c9519')

build() {
  cd towncrier
  python -m build --wheel --no-isolation
}

check() {
  cd towncrier
  python -m installer --destdir=tmp_install dist/*.whl
  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
  PYTHONPATH="$PWD/tmp_install/usr/lib/python${python_version}/site-packages" PATH="$PWD/tmp_install/usr/bin:$PATH" trial towncrier
}

package() {
  cd towncrier
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}

# vim:set ts=2 sw=2 et:
