# Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>

_gemname='temple'
pkgname="ruby-${_gemname}"
pkgver=0.10.4
pkgrel=1
pkgdesc='Template compilation framework in Ruby'
arch=('any')
url="https://github.com/judofyr/${_gemname}"
license=('MIT')
depends=(
  ruby
)
makedepends=(
  git
)
checkdepends=(
  ruby-bundler
  ruby-erubi
  ruby-rake
  ruby-rspec
  ruby-tilt
)
options=('!emptydirs')
source=("${pkgname}::git+${url}.git#tag=v${pkgver}")
sha512sums=('ac99f8d84b7d9c80e6caa241c5b46241dcde82abb2d2791eb7d148af7fdf0fa3e8b1d0a956efc2c30316133abf272444d97bb109a809e7fc8ba76b7f5c5e6350')
b2sums=('d891dfe154210d206098a584cecc9a805fb2c7ae21b3d98c873f28f5bd0ebdd2fcda31725d3c97694ea58d5c08c293c5ba1b240ef2bbed6c172b3646fd01d467')

prepare() {
  cd "${pkgname}"

  # update gemspec/Gemfile to allow newer version of the dependencies
  sed --in-place --regexp-extended 's|~>|>=|g' "${_gemname}.gemspec"
}

build() {
  cd "${pkgname}"

  local _gemdir="$(gem env gemdir)"

  gem build "${_gemname}.gemspec"

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "tmp_install/${_gemdir}" \
    --bindir "tmp_install/usr/bin" \
    "${_gemname}-${pkgver}.gem"

  # remove unrepreducible files
  rm --force --recursive --verbose \
    "tmp_install/${_gemdir}/cache/" \
    "tmp_install/${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
    "tmp_install/${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"

  find "tmp_install/${_gemdir}/gems/" \
    -type f \
    \( \
      -iname "*.o" -o \
      -iname "*.c" -o \
      -iname "*.so" -o \
      -iname "*.time" -o \
      -iname "gem.build_complete" -o \
      -iname "Makefile" \
    \) \
    -delete

  find "tmp_install/${_gemdir}/extensions/" \
    -type f \
    \( \
      -iname "mkmf.log" -o \
      -iname "gem_make.out" \
    \) \
    -delete
}

check() {
  cd "${pkgname}"

  local _gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install/${_gemdir}" rake spec
}

package() {
  cd "${pkgname}"

  cp --archive --verbose tmp_install/* "${pkgdir}"

  install --verbose -D --mode=0644 LICENSE* --target-directory "${pkgdir}/usr/share/licenses/${pkgname}"
  install --verbose -D --mode=0644 CHANGES *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}
