# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>

_gemname=rouge
pkgname=ruby-rouge
pkgver=4.6.1
pkgrel=1
pkgdesc='Pure-ruby code highlighter that is compatible with pygments'
url='https://rouge.jneen.net/'
arch=('any')
license=('MIT')
depends=(
  ruby
)
makedepends=(
  ruby-rdoc
)
checkdepends=(
  ruby-bundler
  ruby-memory_profiler
  ruby-minitest
  ruby-minitest-power_assert
  ruby-mutex_m
  ruby-pry
  ruby-puma
  ruby-rake
  ruby-redcarpet
  ruby-sinatra
  ruby-yard
)
options=('!emptydirs')
source=("https://github.com/jneen/rouge/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('6ae27ed649bd9fc08aa4fe69cd03ae14772c2ced4616b12337b5f9aa8fa7e5694aa98fe2c6f945a7fbd6b1f12a22c2af365068ff73d79d0f247a8acf2f8a6ad3')
b2sums=('e03135483f71f929f4d29094dfb42ef7f47c08817594911332f656db5031db340f77f80407a8dc27ef36b4952f1b8e23059371b69cc9ed24ad4a67bef5e7a1ae')

prepare() {
  cd "${_gemname}-${pkgver}"

  # update gemspec/Gemfile to allow newer version of the dependencies
  sed --in-place --regexp-extended 's|~>|>=|g' "${_gemname}.gemspec"

  sed --in-place --regexp-extended \
    --expression '/changelog/d' \
    --expression '/git/d' \
    --expression '/rubocop/d' \
    --expression '/shotgun/d' \
    Gemfile \
    Rakefile

  rm --verbose \
    tasks/check/style.rake \
    tasks/update/changelog.rake
}

build() {
  cd "${_gemname}-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  gem build --verbose "${_gemname}.gemspec"

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "tmp_install${_gemdir}" \
    --bindir "tmp_install/usr/bin" \
    "${_gemname}-${pkgver}.gem"

  # remove unrepreducible files
  rm --force --recursive --verbose \
    "tmp_install${_gemdir}/cache/" \
    "tmp_install${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
    "tmp_install${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"

  find "tmp_install${_gemdir}/gems/" \
    -type f \
    \( \
      -iname "*.o" -o \
      -iname "*.c" -o \
      -iname "*.so" -o \
      -iname "*.time" -o \
      -iname "gem.build_complete" -o \
      -iname "Makefile" \
    \) \
    -delete

  find "tmp_install${_gemdir}/extensions/" \
    -type f \
    \( \
      -iname "mkmf.log" -o \
      -iname "gem_make.out" \
    \) \
    -delete
}

check() {
  cd "${_gemname}-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install${_gemdir}" rake check:specs check:warnings
}

package() {
  cd "${_gemname}-${pkgver}"

  cp --archive --verbose tmp_install/* "${pkgdir}"

  install --verbose -D --mode=0644 LICENSE* --target-directory "${pkgdir}/usr/share/licenses/${pkgname}"
  install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: tabstop=2 shiftwidth=2 expandtab:
