# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=ruby-ffi-compiler
pkgver=1.3.2
pkgrel=1
pkgdesc='Ruby library for automating compilation of native libraries for use with ffi'
arch=(any)
url='https://github.com/ffi/ffi-compiler'
license=(Apache-2.0)
depends=(ruby-ffi ruby-rake)
makedepends=(git ruby-rspec ruby-rubygems-tasks ruby-rdoc)
options=(!emptydirs)
source=(git+https://github.com/ffi/ffi-compiler.git#tag=$pkgver)
sha256sums=('cf7d2bd2e841512b2f097b4e631b8147d9738e09cf629b56d5e587542bcab800')

build() {
  local _gemdir="$(gem env gemdir)"
  cd ffi-compiler
  rake build
  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "tmp_install/$_gemdir" \
    --bindir "tmp_install/usr/bin" \
    pkg/ffi-compiler-$pkgver.gem
  find "tmp_install/$_gemdir/gems/" \
    -type f \
    \( \
        -iname "*.o" -o \
        -iname "*.c" -o \
        -iname "*.so" -o \
        -iname "*.time" -o \
        -iname "gem.build_complete" -o \
        -iname "Makefile" \
    \) \
    -delete
  rm -r tmp_install/$_gemdir/cache
}

check() {
  local _gemdir="$(gem env gemdir)"
  cd ffi-compiler
  # Should output: Example.example=deadbeef
  # TODO: Disabled because example needs to be built first.
  # GEM_HOME="tmp_install/$_gemdir" ruby <<< 'require "example/example"; puts "Example.example=#{Example.example.to_s(16)}"'
}

package() {
  cd ffi-compiler
  cp -a tmp_install/* "$pkgdir"/
}
