# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Simon Hanna <simon dot hanna AT serve-me DOT info>

pkgname=python-zope-event
_pkgname=zope.event
pkgver=6.1
pkgrel=1
pkgdesc="Provides a simple event system"
arch=(any)
url="https://github.com/zopefoundation/zope.event"
license=('ZPL-2.1')
depends=('python')
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
  'python-wheel'
)
checkdepends=('python-zope-testrunner')
source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('abb824463ef4794b7729473c57c0ce7717473fa4db5b057dbd72b3473bdd55ea118ed4b9208ca191e0f530deeb15816a636d5fb170ad5b488d79b67d46e485e5')

build() {
  cd $_pkgname-$pkgver
  python -m build --wheel --no-isolation --skip-dependency-check
}

check() {
  cd $_pkgname-$pkgver
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl
  test-env/bin/python -m zope.testrunner -vc --test-path src/
}

package() {
  cd $_pkgname-$pkgver
  python -m installer --destdir="$pkgdir" dist/*.whl
}
