# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=th-lift
pkgname=haskell-th-lift
pkgver=0.8.6
pkgrel=2
pkgdesc="Derive Template Haskell's Lift class for datatypes."
url="https://github.com/RyanGlScott/th-lift"
license=('BSD-3-Clause')
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-th-abstraction')
makedepends=('ghc')
source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
sha512sums=('88164a8805bb5a3036b796b485ff5fc9b76b3b3b2b71b0fe57bc0206751575aad2787c368f6769e1d7309ad0e3e50963c80a356096906e01d31c6bd1872897b8')

build() {
    cd $_hkgname-$pkgver
    
    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver
    
    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 "BSD3" "${pkgdir}/usr/share/licenses/${pkgname}/BSD3"
    rm -f "${pkgdir}/usr/share/doc/${pkgname}/BSD3"
}
