# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Maintainer (Holo): Manuel A. Fernandez Montecelo <mafm@igalia.com>

pkgname=upower
pkgver=1.90.10
pkgrel=1.1
pkgdesc="Abstraction for enumerating power devices, listening to device events and querying history and statistics"
url="https://upower.freedesktop.org"
arch=(x86_64)
license=(GPL-2.0-or-later)
depends=(
  gcc-libs
  glib2
  glibc
  libgudev
  libimobiledevice
  libplist
  polkit
)
makedepends=(
  docbook-xsl
  git
  glib2-devel
  gobject-introspection
  gtk-doc
  meson
  python
  systemd
  usbmuxd
)
optdepends=('usbmuxd: Read charge status of iOS devices')
checkdepends=(
  python-dbus
  python-dbusmock
  python-gobject
  python-packaging
  umockdev
)
backup=(etc/UPower/UPower.conf)
source=("git+https://gitlab.freedesktop.org/upower/upower.git#tag=v$pkgver")
b2sums=('bd3add1a05b237576b6829e92fb83535d5be3d9fe1b46d29fb388984cc6d54684abd6d0ad1482f148a138916528f0f4e9c4252f13b636b3c9359dbcea51c384a')

prepare() {
  cd upower
}

build() {
  arch-meson upower build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  depends+=(libg{lib,object,io}-2.0.so)
  provides+=(libupower-glib.so)

  meson install -C build --destdir "$pkgdir"

  # Remove installed-tests
  rm -rv "$pkgdir"/usr/{lib/upower,share/installed-tests}

  # Holo: Set CriticalPowerAction to Ignore, this task is done by vpower/Steam
  echo "Holo: Setting CriticalPowerAction=Ignore in UPower.conf, done by vpower/Steam" \
       "      (this will fail if changes did not happen as expected):"
  sed -i '/^AllowRiskyCriticalPowerAction=/ s/=false/=true/;/^CriticalPowerAction=/ s/=.*$/=Ignore/' "$pkgdir/etc/UPower/UPower.conf"
  grep '^AllowRiskyCriticalPowerAction=true$' "$pkgdir/etc/UPower/UPower.conf"
  grep '^CriticalPowerAction=Ignore$' "$pkgdir/etc/UPower/UPower.conf"
}

# vim:set sw=2 sts=-1 et:
